/**  Garden1

2007 by Duncan Holby. www.glyfconstruct.com
Protected under the Creative Commons Licence. For non-commerical use only. 
Feel free to use but please credit.

For use with Flower4.as or Flower5.as, Pedal.as. 

**/

package {
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;

	public class Garden1 extends Sprite {
		private var i:uint = 0;
		private var j:uint = 0;
		private var k:uint = 0;
		private var n:uint = 0;
		private var seeds:Array = new Array();
		private var eventSprite:Sprite;
		private var numFlowers:uint =30;
		private var minRadius:uint = 5;
		private var flowerXpos:Array = new Array();
		private var flowerYpos:Array = new Array();
		private var flowerRadius:Array = new Array();
		private var distance:Array = new Array();
		public function Garden1() {
			init();
		}
		
		private function init():void {
			seeder();
			stage.addEventListener(MouseEvent.MOUSE_DOWN, onmouseDown);
		}
		private function onmouseDown(event:Event):void {
			//reset
			for(k=0; k<numFlowers; k++){
				removeChild(seeds[k]);
			};
			seeder();
		}
		private function seeder():void {
			//determines starting points and radius of first two "flowers"
			flowerXpos[0] = 100+Math.random()*600;
			flowerYpos[0] = 100+Math.random()*400;
			flowerXpos[1] = 100+Math.random()*600;
			flowerYpos[1] = 100+Math.random()*400;
			var xDist:Number = Math.abs(flowerXpos[0] - flowerXpos[1]);
			var yDist:Number = Math.abs(flowerYpos[0] - flowerYpos[1]);
			var firstDistance:Number = Math.sqrt(Math.abs(xDist*xDist + yDist*yDist));
			flowerRadius[0] = firstDistance*.75;
			flowerRadius[1] = firstDistance*.25;
			
			//determines starting points and radius for remaining "flowers" (radius is distance to existing flower)
			i = 2;
			while(i <= numFlowers) {
				flowerXpos[i] = 100+Math.random()*600;
				flowerYpos[i] = 100+Math.random()*400;
				for(j=0; j<i; j++){
					xDist = Math.abs(flowerXpos[i] - flowerXpos[j]);
					yDist = Math.abs(flowerYpos[i] - flowerYpos[j]);
					distance[j] = Math.sqrt(Math.abs(xDist*xDist + yDist*yDist)) - flowerRadius[j];		
				}
				//gets distance to closest edge of existing flowers, records values only if
				//position is not already occupied by an existing flower or is below the minRadius
				distance.sort(Array.NUMERIC);
				
				if (distance[0] > minRadius){
					flowerRadius[i] = distance[0];
					i++;
				};
					
				 
			};		
			//adds all flowers to the display
			for(k=0; k<numFlowers; k++){
				seeds[k] = new Flower5(flowerRadius[k]);
				seeds[k].x = flowerXpos[k];
				seeds[k].y = flowerYpos[k];
				addChild(seeds[k]);
			};
		};
	};
};